*  This is file VENTRICL.SAS  ;
*     Create data set from pulmonary artery constriction only     ;
DATA;
     infile vent1;
     input Aed Ped Dr;
     *   set up to create centered variables by making copies   ;
     *   of the variables to be centered                        ;
     cPed=Ped;
     cDr=Dr;
*   use proc STANDARD with no STD specification to subtract means    ;
*   which overwrites cPed and cDr with centered values and retains   ;
*   other variables in unmodified form.                              ;
proc STANDARD mean=0;
     var cPed cDr;
DATA vent1;
*    Get last data set (from proc STANDARD)   ;
     set;
     Ped2=Ped**2;
     PedDr=Ped*Dr;
     cPed2=cPed**2;
     cPedDr=cPed*cDr;
     LABEL Aed='Left Ventricle end-diastolic area'
           Ped='Left Ventricle end-diastolic pressure'
           Dr ='Right Ventrilce end-diastolic dimension'
           Ped2='Squared end-diastolic pressure'
           PedDr='Pressure by dimension interaction'
           cPed='Centered end-diastolic pressure'
           cPed2='Squared centered end-diastolic pressure'
           cDr='Centered end-diastolic dimension'
           cPedDr='Centered press. by dimension interaction';
*     Create data set from sequence of pulmonary artery and       ;
*     vena caval constrictions and releases (Data in Table C-12B) ;
DATA temp1;
     infile vent2;
     input Aed Ped Dr;
     cPed=Ped;
     cDr=Dr;
proc STANDARD mean=0;
     var cPed cDr;
DATA vent2;
     set;
     Ped2=Ped**2;
     PedDr=Ped*Dr;
     cPed2=cPed**2;
     cPedDr=cPed*cDr;
     LABEL Aed='Left Ventricle end-diastolic area'
           Ped='Left Ventricle end-diastolic pressure'
           Dr ='Right Ventricle end-diastolic dimension'
           Ped2='Squared end-diastolic pressure'
           PedDr='Pressure by dimension interaction'
           cPed='Centered end-diastolic pressure'
           cPed2='Squared centered end-diastolic pressure'
           cDr='Centered end-diastolic dimension'
           cPedDr='Centered press. by dimension interaction';
*  Regression of raw (i.e., uncentered) data from first data set: Vent1  ;
*  followed by centered data regression, including collinearity          ;
*  diagnostics with /VIF (for VIF) and COLLINOINT (for eigenvalues and   ;
*  condition indices from correlation matrix)                            ;
proc REG  data=vent1;
        model Aed = Ped Ped2 Dr PedDr/ VIF COLLINOINT;
        model Aed = cPed cPed2 cDr cPedDr/ VIF COLLINOINT;
*  Regression of raw (i.e., uncentered) data from second data set: Vent2 ;
*  followed by centered data regression, including collinearity          ;
*  diagnostics with /VIF (for VIF) and COLLINOINT (for eigenvalues and   ;
*  condition indices from correlation matrix)                            ;
proc REG  data=vent2;
        model Aed = Ped Ped2 Dr PedDr/ VIF COLLINOINT;
        model Aed = cPed cPed2 cDr cPedDr/ VIF COLLINOINT;